Egal ob in der Schule oder im Studium: Es gibt Noten und am Ende einen Notenschnitt. Heute wollen wir schauen wie mit Hilfe von Excel der aktuelle sowie ein möglicher Notenschnitt errechnet werden kann. Keine Angst, ist nur halb so trocken wie es klingt.
Disclaimer: Templates werden „as-is“ ohne jede Garantie als Beispiele bereitgestellt. Bitte rechnet immer nach – denn Fehler können jedem passieren.
Download “Notenrechner für Studium und Schule in Excel”
Tabellendoktor.de-Notenrechner.xlsx – 2613-mal heruntergeladen – 19,45 kBVerwendete Excel-Funktionen
- SUMME/SUM
- SUMMEWENN/SUMIF
- WENN/IF
- Tabellen
- Pivot-Tabelle
- PIVOTDATENZUORDNEN/GETPIVOTDATA
Die Frage: Wie gut kann es noch werden? Und wo stehe ich?
Egal ob noch ziemlich am Anfang der Schul- oder Studienlaufbahn, die Frage ist schnell wie gut bin ich denn so? Und wie gut (oder auch schlecht) kann der Notendurchschnitt noch werden? Daraus läßt sich dann auch gut ableiten wo es sich lohnt richtig Gas zu geben und wo es eigentlich auch egal ist.
Eingabe-Parameter
Klingt technisch – aber was brauchen wir denn für unsere Frage?
- Prüfungen, Fächer oder Module mit ihrem Gewicht für die Gesamtnote (also im Studium ECTS als Gewicht)
- Gesamtzahl der erreichbaren Credits bzw. die Summer aller Gewichte
- Bereits erreichte Noten
- Für welche Noten soll gerechnet werden bei Fächern ohne Note bisher? 1,0 und 4,0 als Extreme bieten sich immer an – nur das dazwischen sollte dynamisch sein
Do-It-Yourself-Variante: Schritt-für-Schritt zum Notenrechner-Glück
Wir brauchen nicht mehr als eine leere Excel-Datei. Und die speichern wir auch direkt, damit „unterwegs“ nichts verloren geht:
(Für die Interessierten: Das ist Excel 365 auf dem Mac im Dark Mode(„dunkles Erscheinungsbild“) – auch wenn bei Euch Excel anders aussehen sollte, die Funktionen sind die Gleichen)
Schritt 0 (Vorbereitung): Sicherstellen, dass zwei Arbeitsblätter „Szenarien“ und „Noten“ vorhanden sind. Je nach Excel-Version sind sogar schon ein oder mehrere Blätter angelegt („Blatt 1“, „Tabelle1“ o.ä.):
1. Wenn uns ein Blatt da ist: Neben dem Namen ist ein „+“ (Plus) und damit ein neues Blatt dann hinzufügen
2. Blätter entsprechend benennen: einfach schnell zwei Mal (Doppelklick) auf den Blattnamen klicken und die Namen ändern
Schritt 1: Festlegung Szenarien für mögliche Noten in einer Tabelle
1. Auf dem Blatt „Szenarien“ kommen zwei „Überschriften“ in die ersten beiden Zellen: „Szenario“, „Note“
2. Da drunter schreiben wir jetzt 5 mögliche Szenarien mit Namen auf – hier als Beispiel
3. Jetzt alle Zellen mit dem Inhalt markieren und als Tabelle formatieren– Farben und Co. nach eigenem Geschmack wählen
4. Ja die Tabelle hat Überschriften und mit „OK“ bestätigen
5. Tabelle noch benennen – dazu in die Tabelle klicken (beliebige Zelle darin) und dann im „Ribbon“ Tabelle den Namen auf „TabSzenarien“ ändern – Bilder:
Fertig – unsere Szenarien stehen
Schritt 2: Aufbau einer Tabelle für die Erfassung der Fächer nach Modulen auf dem Blatt „Noten“
0. Auf das andere Tabellenblatt „Noten“ wechseln
1. Überschriften aufschreiben: Modul, Fach, ECTS, Erreichte Note
2. Genau die vier Zellen und die vier Zellen darunter markieren
3. Jetzt als „Tabelle formatieren“ / „Format as table“ – Farben und Co. nach eigenem Geschmack wählen
4. Wichtig: „Tabelle hat Überschriften“ anhaken und mit Klick auf OK bestätigen
Jetzt haben wir eine Erfasungstabelle.
Schritt 3: Daten erfassen – ansonsten bleibt es ab hier arg abstrakt
1. Module und Fächer sowie ECTS aufschreiben
2. bereits erreichte Noten nachtragen
Als Beispiel dient ein fiktiver Studiengang der Tabellogie mit wenigen Fächern und ein paar erreichten Noten:
Schritt 4: Tabelle mit Gewichtungen erweitern – zur Vereinfachung bauen wir das in der gleichen Tabelle, in der reinen Lehre würde das auf ein eigenes Tabellenblatt ausgelagert werden
1. In die Zellen direkt rechts neben der Überschrift „Erreichte Note“ schreiben wir die nächsten Überschriften: „Anteil an Modulnote“, „Anteil an Gesamtnote“ – dadurch wird die Tabelle breiter (Überschrift sollte direkt richtig formatiert sein)
2. Formel für die Berechnung des Anteils an der Modulnote in die erste Zelle unter der Überschrift dazu schreiben:=[@ECTS]/SUMMEWENN([Modul];[@Modul];[ECTS]) (deutsch) bzw. =[@ECTS]/SUMIF([Modul];[@Modul];[ECTS]) (englisch)
3. Sobald die Formel „bestätigt“ ist (Return-Taste drücken) sollte die ganze Spalte gefüllt sein:
4. Und jetzt das auch noch einmal für den Anteil an der Gesamtnote:
=[@ECTS]/SUMME([ECTS])
5. Jetzt beide Spalten noch als Prozent formatieren damit es hübscher aussieht
Schritt 5: Jetzt kommen gewichtete Noten dazu – auch wieder in der gleichen Tabelle
1. Wir ergänzen wieder Überschriften auf der rechten Seite:
- Modul – erreicht
- Modul – Szenario 1
- Modul – Szenario 2
- Modul – Szenario 3
- Modul – Szenario 4
- Modul – Szenario 5
- Gesamt – erreicht
- Gesamt – Szenario 1
- Gesamt – Szenario 2
- Gesamt – Szenario 3
- Gesamt – Szenario 4
- Gesamt – Szenario 5
2. Jetzt kommen zunächst die einfachen Formeln für die bereits erreichten Noten – für Modul – erreicht=[@[Erreichte Note]]*[@[Anteil an Modulnote]]
Für die Spalte Gesamt – erreicht=[@[Erreichte Note]]*[@[Anteil an Gesamtnote]]
3. Jetzt wird es spannender für die Szenarien pro Modul – die sollen nur für noch nicht erreichte Noten berechnet werden. Daher muss das in den Formeln „abgefragt“ werden. Los geht’s mit Modul – Szenario 1:=WENN([@[Modul - erreicht]]>0;[@[Modul - erreicht]];[@[Anteil an Modulnote]]*INDEX(TabSzenarien[Note];1)) (deutsch)
bzw. =IF([@[Modul - erreicht]]>0;[@[Modul - erreicht]];[@[Anteil an Modulnote]]*INDEX(TabSzenarien[Note];1)) (englisch)
Kurz erklärt: Wenn in der Spalte Modul – erreicht schon ein Wert größer 0 steht, wird der genommen, ansonsten multiplizieren wir den Anteil an der Modulnote mit der Note die in der Tabelle TabSzenarien in Spalte Note in der Zeile 1 steht. In einem englischen Excel würde in der Formel statt WENN einfach IF stehen. Der Rest bleibt gleich.
Für Modul – Szenario 2 lautet die Formel dann:=WENN([@[Modul - erreicht]]>0;[@[Modul - erreicht]];[@[Anteil an Modulnote]]*INDEX(TabSzenarien[Note];2))
Der Unterschied ist wie man sieht nur die Zeile in der INDEX-Formel, entsprechend lautet die Formel dann für die Szenarien 3, 4 und 5 jeweils:=WENN([@[Modul - erreicht]]>0;[@[Modul - erreicht]];[@[Anteil an Modulnote]]*INDEX(TabSzenarien[Note];3))=WENN([@[Modul - erreicht]]>0;[@[Modul - erreicht]];[@[Anteil an Modulnote]]*INDEX(TabSzenarien[Note];4))=WENN([@[Modul - erreicht]]>0;[@[Modul - erreicht]];[@[Anteil an Modulnote]]*INDEX(TabSzenarien[Note];5))
4. Weiter geht es mit der Berechnung für die Gesamtnote in den Szenarien. Hier sehen die Formeln dann so aus (wieder ändert sich nur die Zahl in der Index-Formel je nach Szenario):=WENN([@[Gesamt - erreicht]]>0;[@[Gesamt - erreicht]];[@[Anteil an Gesamtnote]]*INDEX(TabSzenarien[Note];1))
=WENN([@[Gesamt - erreicht]]>0;[@[Gesamt - erreicht]];[@[Anteil an Gesamtnote]]*INDEX(TabSzenarien[Note];2))=WENN([@[Gesamt - erreicht]]>0;[@[Gesamt - erreicht]];[@[Anteil an Gesamtnote]]*INDEX(TabSzenarien[Note];3))=WENN([@[Gesamt - erreicht]]>0;[@[Gesamt - erreicht]];[@[Anteil an Gesamtnote]]*INDEX(TabSzenarien[Note];4))=WENN([@[Gesamt - erreicht]]>0;[@[Gesamt - erreicht]];[@[Anteil an Gesamtnote]]*INDEX(TabSzenarien[Note];5))
So fertig mit der Berechnung – jetzt geht es an die Auswertung
Schritt 6: Daten auswerten fürs Gesamtergebnis – denn jetzt wollen wir wissen wo wir stehen und wie gut es noch werden kann
1. Wir gehen wieder auf das Blatt „Szenarien“
2. Neben der Überschrift „Note“ schreiben wir in die Zelle rechts davon „Resultierendes Gesamtergebnis“ 
3. Darunter kommt als Formel in die erste Zelle hinein:=SUMME(Tabelle1[Gesamt - Szenario 1]) (deutsch) bzw. =SUM(Tabelle1[Gesamt - Szenario 1]) (englisch)
Das übernimmt Excel dann in alle Zeilen, was inhaltlich natürlich nicht richtig ist:
4. Zur Lösung gibt es zwei Möglichkeiten:
a) Auf das neu erschienene Symbol klicken und „Berechnete Spalte rückgängig“ auswählen
b) Einfach „Rückgängig“ machen – entweder über das Menü „Bearbeiten“ oder durch die Tastenkombination STRG+Z / CTRL+Zbzw. ⌘+Z
5. Jetzt in den folgenden Zeilen wieder die Formeln einfügen und – wenn es passieren sollte, da ist Excel nicht immer konsistent – die Übernahme in die anderen Zeilen verhindern (siehe Schritt 4):=SUMME(Tabelle1[Gesamt - Szenario 2])=SUMME(Tabelle1[Gesamt - Szenario 3])=SUMME(Tabelle1[Gesamt - Szenario 4])=SUMME(Tabelle1[Gesamt - Szenario 5])
6. Geschafft – jetzt wissen wir was insgesamt rauskommt, wenn wir alle weiteren Prüfungen bzw. Leistungen mit einer bestimmten Note schaffen:
Schritt 7: Aufbau der Auswertung pro Modul – das ist schon etwas trickreicher, da die Namen der Module ja frei wählbar sind und wir daher eine Pivot-Tabelle verwenden
1. Auf dem Blatt „Noten“ klicken wir auch unsere Notentabelle – einfach mittel rein einmal
2. Neue Pivot-Tabelle einfügen über das Menü „Einfügen“->“PivotTable“/“Pivot-Tabelle“
bzw. „Insert“->“PivotTable“
oder es ist direkt sichtbar 
3. Automatisch schlägt Excel die Tabelle in der wir gerade sind als Quelle vor – das passt schon. Als Ort für die Tabelle geben wir ein vorhandenes Blatt an und wählen Szenarien!$A$14 – damit landet die Pivot-Tabelle auf unserem Blatt „Szenarien“ ab Zelle A14
4. Zurück auf dem Blatt „Szenarien“ konfigurieren wir nun die Pivot-Tabelle für unsere Auswertung. Dazu ziehen wir als erstes „Modul“ aus der Liste der Felder in den Kasten Zeilen. Das Ergebnis sieht dann so aus:
5. Jetzt ergänzen wir die Ergebnisse für jedes Szenario pro Modul: Hierzu werden die Felder Modul – Szenario 1, Modul – Szenario 2, Modul – Szenario 3, Modul – Szenario 4 und Modul – Szenario 5 unten in den Kasten Werte gezogen. Dabei macht Excel da normalerweise auch Summen draus (wenn nicht über der Infosymbol jeweils anpassen):
Schritt 8: Erinnerung an die Aktualisierung der Pivot-Tabelle. Warum? Pivot-Tabellen müssen manuell aktualisiert werden per Rechtsklick und dann Auswahl von „aktualisieren“ ansonsten bleiben alte Werte drin. Damit wir das erkennen:
1. In Zelle B10 kommt diese Formel zur Berechnung der „Summe in Pivot“:=SUMME(PIVOTDATENZUORDNEN("Summe von Modul - Szenario 1";$A$14);PIVOTDATENZUORDNEN("Summe von Modul - Szenario 2";$A$14);PIVOTDATENZUORDNEN("Summe von Modul - Szenario 3";$A$14);PIVOTDATENZUORDNEN("Summe von Modul - Szenario 4";$A$14);PIVOTDATENZUORDNEN("Summe von Modul - Szenario 5";$A$14)) bzw. für die englischsprachige Excel-Version=SUM(GETPIVOTDATA("Summe von Modul - Szenario 1";$A$14);GETPIVOTDATA("Summe von Modul - Szenario 2";$A$14);GETPIVOTDATA("Summe von Modul - Szenario 3";$A$14);GETPIVOTDATA("Summe von Modul - Szenario 4";$A$14);GETPIVOTDATA("Summe von Modul - Szenario 5";$A$14))
2. In Zelle B11 kommt dann die „Summe in Berechnung“:=SUMME(Tabelle1[[Modul - Szenario 1]:[Modul - Szenario 5]]) bzw. =SUM(Tabelle1[[Modul - Szenario 1]:[Modul - Szenario 5]])
3. Und in Zelle B12 beantworten wir die Frage „Pivot muss aktualisiert werden?“:=WENN(B10<>B11;"ja";"nein")bzw. =IF(B10<>B11;"ja";"nein")
Schritt 9: Formatieren nach Belieben – mein Vorschlag dafür (auch umgesetzt im Download)
1. Weißer Hintergrund für alle Zellen – außer die Tabellenköpfe/-Überschriften
2. Eingabefelder markieren – mit dem vordefinierten Standardformat dafür
3. Überschriften hinzufügen
Fertig!
Download “Notenrechner für Studium und Schule in Excel”
Tabellendoktor.de-Notenrechner.xlsx – 2613-mal heruntergeladen – 19,45 kB